@echo off
chcp 936 >nul
title 去掉桌面快捷方式小箭头
:menu
cls
echo ===========================================
echo    桌面快捷方式小箭头 去/恢复 工具
echo ===========================================
echo.
echo    [1] 去掉小箭头和「快捷方式」字样
echo    [2] 恢复成 Windows 默认样式
echo    [0] 退出
echo.
set /p choice=请输入数字后回车: 
if "%choice%"=="1" goto remove
if "%choice%"=="2" goto restore
if "%choice%"=="0" exit /b
goto menu

:remove
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons" /v 29 /t REG_SZ /d "%%SystemRoot%%\System32\shell32.dll,-50" /f >nul
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\NamingTemplates" /v ShortcutNameTemplate /t REG_SZ /d "%%s.lnk" /f >nul
echo.
echo 已去掉小箭头，正在重启资源管理器...
taskkill /f /im explorer.exe >nul 2>nul
start explorer.exe
echo 完成。没生效的话注销一次或重启即可。
pause
goto menu

:restore
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons" /v 29 /f >nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\NamingTemplates" /v ShortcutNameTemplate /f >nul 2>nul
echo.
echo 已恢复默认样式，正在重启资源管理器...
taskkill /f /im explorer.exe >nul 2>nul
start explorer.exe
echo 完成。
pause
goto menu